| 项目搜索 |
| |
|
代码片段库:
查看代码片段
浏览
| 提交新的代码片段
| 创建代码包
使用ADO存储XML文件
|
类型:
Sample Code (HOWTO) |
类别:
Other
|
许可证:
GNU General Public License |
语言:
Other Language
|
描述:
使用ADO存储XML文件
|
该代码片段的版本系列:
片段ID |
下载版本 |
提交时间 |
提交人 |
删除 |
4741 | 1.0 | 2003-10-19 22:14 | cbd001 | |
点击"下载版本"来下载该代码片段.
最新版本的代码片段: 1.0
<%
'*******************************************************
'* ASP 101 Sample Code - http://www.asp101.com *
'* *
'* This code is made available as a service to our *
'* visitors and is provided strictly for the *
'* purpose of illustration. *
'* *
'* Please direct all inquiries to [email protected] *
'*******************************************************
%>
< !-- #include file="adovbs.inc" -->
<%
' Constants file included above.
' Delete existing file
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(Server.MapPath("db_xml.xml")) Then
objFSO.DeleteFile Server.MapPath("db_xml.xml")
End IF
Set objFSO = Nothing
' Declare our variables... always good practice.
Dim cnnXML ' ADO connection
Dim rstXML ' ADO recordset
' Create an ADO Connection to connect to the scratch database.
' We're using OLE DB but you could just as easily use ODBC or a DSN.
Set cnnXML = Server.CreateObject("ADODB.Connection")
' This line is for the Access sample database:
'cnnXML.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" _
' & Server.MapPath("db_scratch.mdb") & ";"
' We're actually using our site-wide SQL Server connection:
cnnXML.Open Application("SQLConnString"), Application("SQLUsername"), _
Application("SQLPassword")
' Execute a query using the connection object. It automatically
' creates and returns a recordset which we store in our variable.
Set rstXML = Server.CreateObject("ADODB.Recordset")
Set rstXML = cnnXML.Execute("SELECT * FROM scratch ORDER BY id;")
Response.Write "Saving data as XML...<br>" & vbCrLf
' Save the file to XML format.
rstXML.Save Server.MapPath("db_xml.xml"), adPersistXML
' Close our recordset and connection and dispose of the objects
rstXML.Close
Set rstXML = Nothing
cnnXML.Close
Set cnnXML = Nothing
Response.Write "XML file written...<br>" & vbCrLf
Response.Write "Click <a href=""db_xml.xml"">here</a> to view the file.<br>" & vbCrLf
%>
如果您修改了一个代码片段并且觉得很应该让别人共享,您可以把这作为这个代码片段的最新版本提交上来. |
|